integration-adaptor-gp2gp-requesting/db-connector/build.gradle at 69c099e6c8f1e00d254223d58533d2da01114ad6 · NHSDigital/integration-adaptor-gp2gp-requesting · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.liquibase:liquibase-gradle-plugin:3.0.2"
        classpath 'org.liquibase:liquibase-core:4.31.0'
    }
}

plugins {
    id 'org.springframework.boot' version '3.5.7'
    id 'io.spring.dependency-management' version '1.1.7'
    id 'java'
    id 'checkstyle'
    id 'io.freefair.lombok' version '9.0.0'
    id 'com.github.spotbugs' version '6.4.2'
}

apply plugin: 'java'
apply plugin: 'org.springframework.boot'
apply plugin: 'checkstyle'
apply plugin: 'com.github.spotbugs'
apply plugin: 'org.liquibase.gradle'

repositories {
    mavenCentral()
}

dependencies {
    implementation project(':common')
    implementation 'org.postgresql:postgresql:42.7.5'
    implementation 'org.jdbi:jdbi3-core:3.49.5'
    implementation 'org.jdbi:jdbi3-sqlobject:3.49.5'
    implementation 'org.jdbi:jdbi3-postgres:3.49.5'

    liquibaseRuntime 'org.apache.commons:commons-lang3:3.17.0'
    liquibaseRuntime 'org.liquibase:liquibase-core:4.31.0'
    liquibaseRuntime 'org.liquibase:liquibase-groovy-dsl:4.0.1'
    liquibaseRuntime 'info.picocli:picocli:4.7.6'
    liquibaseRuntime 'org.postgresql:postgresql:42.7.5'
    liquibaseRuntime 'org.yaml:snakeyaml:2.4'
    testImplementation 'junit:junit:4.13.2'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.junit.jupiter:junit-jupiter:6.0.0'
}

test {
    useJUnitPlatform()
    testLogging {
        events "PASSED", "SKIPPED", "FAILED"
    }
}

sourceSets {
    main {
        resources {
            srcDirs += [ "src/main/java" ]
        }
    }
}

bootJar {
    enabled = false
}


tasks.withType(com.github.spotbugs.snom.SpotBugsTask) {
    excludeFilter = rootProject.file('config/spotbugs/exclude.xml')
    reports {
        xml.enabled = true
        html.enabled = false
    }
}

liquibase {
    activities {
        setup {
            changelogFile 'changelog/setup/db.changelog-setup.xml'
            url System.getenv('PS_DB_URL') + '/postgres'
            username System.getenv('PS_DB_OWNER_NAME')
            password System.getenv('POSTGRES_PASSWORD')
        }

        main {
            changelogFile 'changelog/db.changelog-master.xml'
            url System.getenv('PS_DB_URL') + '/patient_switching'
            username System.getenv('PS_DB_OWNER_NAME')
            password System.getenv('POSTGRES_PASSWORD')
        }

        runList = 'setup, main'
    }
}