build: Add Nix/NixOS support

.gitignore

@@ -80,3 +80,7 @@ web-src/geckodriver.log
 venv/
 /venv2/
 e2e_venv/
+
+# Nix / NixOS
+/result
+/*.qcow2

flake.nix

@@ -0,0 +1,67 @@
+{
+  description = "Script-server";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/26.05";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+  };
+
+  outputs =
+    inputs@{
+      self,
+      nixpkgs,
+      flake-parts,
+      ...
+    }:
+    flake-parts.lib.mkFlake { inherit inputs; } {
+      systems = [
+        "x86_64-linux"
+        "aarch64-linux"
+        "aarch64-darwin"
+      ];
+      perSystem =
+        { pkgs, ... }:
+        {
+          packages = {
+            script-server = pkgs.python3Packages.callPackage ./nix/package.nix { };
+
+            script-server-web = pkgs.callPackage ./nix/package-web.nix { };
+
+            demo = self.nixosConfigurations.demo.config.system.build.vm;
+          };
+
+          formatter = pkgs.nixfmt-tree;
+        };
+    }
+    // {
+      overlays.default = final: prev: {
+        script-server = final.python3Packages.callPackage ./nix/package.nix { };
+
+        script-server-web = final.callPackage ./nix/package-web.nix { };
+      };
+
+      nixosModules.default = import ./nix/module.nix;
+
+      nixosConfigurations.demo = nixpkgs.lib.nixosSystem {
+        modules = [
+          self.nixosModules.default
+          {
+            nixpkgs = {
+              overlays = [ self.overlays.default ];
+              hostPlatform = "x86_64-linux";
+            };
+
+            users.users.root.password = "changeit";
+
+            services = {
+              script-server = {
+                enable = true;
+              };
+            };
+
+            system.stateVersion = "26.05";
+          }
+        ];
+      };
+    };
+}

nix/module.nix

@@ -0,0 +1,75 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}:
+let
+  cfg = config.services.script-server;
+  json = pkgs.formats.json { };
+in
+{
+  options.services.script-server = {
+    enable = lib.mkEnableOption "Whether to enable script-server.";
+
+    package = lib.mkOption {
+      type = lib.types.package;
+      default = pkgs.script-server;
+      description = "Script-server package to use.";
+    };
+
+    package-web = lib.mkOption {
+      type = lib.types.package;
+      default = pkgs.script-server-web;
+      description = "Script-server-web package to use.";
+    };
+
+    settings = lib.mkOption {
+      type = json.type;
+      default = { };
+      description = "Server configuration, see <https://github.com/bugy/script-server/wiki/Server-configuration>.";
+    };
+
+    configuration = lib.mkOption {
+      type = lib.types.str;
+      default = "/var/lib/script-server/conf";
+      description = "Script configuration, see <https://github.com/bugy/script-server/wiki/Script-config>.";
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    environment.systemPackages = [ cfg.package ];
+
+    environment.etc."script-server/conf.json".source =
+      json.generate "script-server-config" cfg.settings;
+
+    # See <https://github.com/bugy/script-server/wiki/Running-as-a-linux-service#systemd>
+    systemd.services.script-server = {
+      enable = true;
+
+      description = "Script Server";
+      after = [ "network.target" ];
+      wantedBy = [ "multi-user.target" ];
+
+      serviceConfig = {
+        Restart = "always";
+        RestartSec = "1s";
+        ExecStart = ''
+          ${cfg.package}/bin/script-server \
+            --config-file /etc/script-server/conf.json \
+            --config-dir ${cfg.configuration} \
+            --log-folder /var/log/script-server \
+            --tmp-folder /tmp
+        '';
+
+        # `main.py` expects `web` to be in working directory.
+        WorkingDirectory = "${cfg.package-web}";
+        StateDirectory = "script-server";
+        LogsDirectory = "script-server";
+
+        DynamicUser = true;
+        PrivateTmp = true;
+      };
+    };
+  };
+}

nix/package-web.nix

@@ -0,0 +1,19 @@
+{ lib, buildNpmPackage }:
+buildNpmPackage {
+  pname = "script-server-web";
+  version = "1.18.0";
+
+  src = ../web-src;
+
+  npmDepsHash = "sha256-aBZDh2NcDU4OpsdTS8JqwGMa8WeIoyW9I6bUwTXfllU=";
+
+  makeCacheWritable = true;
+
+  # See <https://stackoverflow.com/questions/75959563/node-js-err-ossl-evp-unsupported-error-when-running-npm-run-start>
+  NODE_OPTIONS = "--openssl-legacy-provider";
+
+  installPhase = ''
+    mkdir "$out"
+    cp -r ../web "$out"
+  '';
+}

nix/package.nix

@@ -0,0 +1,30 @@
+let
+  toml = builtins.fromTOML (builtins.readFile ./../pyproject.toml);
+in
+{
+  lib,
+  buildPythonPackage,
+  tornado,
+  setuptools,
+}:
+buildPythonPackage {
+  pname = toml.project.name;
+  version = toml.project.version;
+  pyproject = true;
+
+  src = lib.fileset.toSource {
+    root = ./..;
+    fileset = lib.fileset.unions [
+      ./../pyproject.toml
+      ./../src
+    ];
+  };
+
+  build-system = [
+    setuptools
+  ];
+
+  dependencies = [
+    tornado
+  ];
+}